SPARQL

Informations sur le point d’accès SPARQL du projet QDMTL

Le projet QDMTL met à disposition un point d’accès SPARQL permettant d’explorer le jeu de données dans l’état actuel du développement.

Point d’accès SPARQL ↗

Spécification

SPARQL 1.0

Ce point d’accès implémente la spécification SPARQL 1.0 à laquelle s’ajoutent les principales fonctions d’agrégation.

Pour en savoir plus sur cette implémentation, consultez le document disponible à l’adresse suivante :

SPARQL 1.1

Date prévue du déploiement de l’entrepôt RDF avec implémentation de la spécification SPARQL 1.1 :

  • à déterminer

Exemple de requêtes

Bâtiments avec coordonnées géographiques

La liste des bâtiments avec :

  • l’URI contenant la version française du nom de la classe
  • l’étiquette associée au bâtiment
  • le nom du bâtiment lorsqu’une appellation existe
  • les coordonnées géographiques lorsqu’elles sont disponibles

Lien vers la requête ↗

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX qdmtl: <http://onto.qdmtl.ca/>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX geo: <http://www.opengis.net/ont/geosparql#>
PREFIX ecrm: <http://erlangen-crm.org/current/>

SELECT DISTINCT ?uriFr ?label ?appellation ?point
  WHERE {
    ?s a qdmtl:E24_Building ;
      owl:sameAs ?uriFr ;
      ecrm:P1_is_identified_by ?identifier ;
      rdfs:label ?label .
    OPTIONAL {
      ?s ecrm:P53_has_former_or_current_location ?place .
      ?place ecrm:P168_place_is_defined_by ?geoFeature .
      ?geoFeature geo:asGeoJSON ?point . }
    OPTIONAL {
      ?identifier a ecrm:E41_Appellation ;
        rdfs:label ?appellation . }
  }

Photographies avec lien vers le fichier numérique

La liste des photographies portant le numéro d’inventaire 116 :

  • l’URI de la pièce d’archive dans la structure de QDMTL
  • le numéro d’inventaire apparaissant sur la photographie
  • le format du fichier
  • l’URL de la photo dans les Archives de Montréal

Lien vers la requête ↗

PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX rico: <https://www.ica.org/standards/RiC/ontology#>
PREFIX schema: <https://schema.org/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX vocab: <http://vocab.qdmtl.ca/>

SELECT ?record ?noInv ?format ?file
  WHERE {
    ?record a rico:Record ;
      rico:hasOrHadIdentifier ?id ;
      rico:hasInstantiation ?instantiation .
    ?id rico:hasIdentifierType vocab:inventoryNumber ;
      rico:textualValue ?noInv .
    FILTER (?noInv = 116) .

    ?instantiation rico:hasCarrierType vocab:digitalFile ;
      dcterms:format ?mimeType ;
      schema:image ?file .
    ?mimeType skos:prefLabel ?format .
  }

Les objets représentés par une photographie

La liste des photographies avec les bâtiments représentés.

Lien vers la requête ↗

PREFIX rico: <https://www.ica.org/standards/RiC/ontology#>
PREFIX qdmtl: <http://onto.qdmtl.ca/>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX ecrm: <http://erlangen-crm.org/current/>
PREFIX geo: <http://www.opengis.net/ont/geosparql#>

SELECT ?record ?batiment ?point
  WHERE {
    ?record a rico:Record ;
      rico:hasOrHadMainSubject ?s .
    ?s a qdmtl:E24_Building ;
      owl:sameAs ?batiment .
    OPTIONAL {
      ?s ecrm:P53_has_former_or_current_location ?place .
      ?place ecrm:P168_place_is_defined_by ?geoFeature .
      ?geoFeature geo:asGeoJSON ?point .
    }
  }